MAth-Cloud-3.0.0/www.ipsocloud.com/intimamedia.com/flex/com/imt/intimamedia/commands/patient/CreatePatientCommand.as

package com.imt.intimamedia.commands.patient
{
	import com.adobe.cairngorm.control.CairngormEvent;
	import com.imt.flex.cairngormExtended.command.SuperCommand;
	import com.imt.intimamedia.business.PatientDelegate;
	import com.imt.intimamedia.events.patient.CreatePatientEvent;
	import com.imt.intimamedia.model.ApplicationModelLocator;
	import com.imt.intimamedia.views.common.ImtToaster;
	import com.imt.intimamedia.views.physician.patient.PatientFile;
	import com.imt.intimamedia.vo.AppointmentVo;
	import com.imt.intimamedia.vo.ReturnObjectVo;
	
	import mx.resources.ResourceManager;
	import mx.rpc.events.FaultEvent;
	import mx.rpc.events.ResultEvent;
	
	import com.imt.intimamedia.helpers.AES;
	
	/**
	* Commande de création d'un patient
	*/ 
	public class CreatePatientCommand extends SuperCommand
	{
		/**
		* Excecution de la commande
		* 
		* @param event Evénement de type CairngormEvent
		* @return void
		*/
		override public function execute( event : CairngormEvent ) : void
		{
			super.execute( event );
			
			var delegate : PatientDelegate = new PatientDelegate( this );
			
			var createPatientEvent : CreatePatientEvent = CreatePatientEvent( event );
			
			ApplicationModelLocator.getInstance().patientSelected		= createPatientEvent.patient;
			ApplicationModelLocator.getInstance().appointmentSelected	= createPatientEvent.appointment;	
			
			createPatientEvent.patient.firstName = AES.encrypt(createPatientEvent.patient.firstName, ApplicationModelLocator.getInstance().aesKey, AES.BIT_KEY_256);
			createPatientEvent.patient.lastName = AES.encrypt(createPatientEvent.patient.lastName, ApplicationModelLocator.getInstance().aesKey, AES.BIT_KEY_256);
			
			delegate.createPatient( createPatientEvent.patient, createPatientEvent.appointment, createPatientEvent.person, ApplicationModelLocator.getInstance().token );
			
			createPatientEvent.patient.firstName = AES.decrypt(createPatientEvent.patient.firstName, ApplicationModelLocator.getInstance().aesKey, AES.BIT_KEY_256);
			createPatientEvent.patient.lastName = AES.decrypt(createPatientEvent.patient.lastName, ApplicationModelLocator.getInstance().aesKey, AES.BIT_KEY_256);
		}
		
		/**
		* Résultat de la commande
		* 
		* @param result Un objet 
		* @return void
		*/
		override public function result( result : Object ) : void
		{
			var dispatcher : PatientFile = this.getDispatcher(this);
			dispatcher.createPatientCompleted();
			
			var resultEvent : ResultEvent = ResultEvent( result );
			
			var returnObjectVo : ReturnObjectVo 							= resultEvent.result as ReturnObjectVo;
			ApplicationModelLocator.getInstance().token						= returnObjectVo.token;
			
			ApplicationModelLocator.getInstance().patientSelected.id	= returnObjectVo.value;
			
			super.result( result );
		}
		
		/**
		* Résultat de la commande
		* 
		* @param result Un objet 
		* @return void
		*/
		override public function fault( fault : Object ) : void
		{
			super.fault( fault );
			
			if (( fault as FaultEvent ).fault.faultString == ApplicationModelLocator.getInstance().ERROR_SESSION )
			{
				ApplicationModelLocator.displaySessionExpired( fault as FaultEvent );
			} 
			else 
			{
				var toastMessage : ImtToaster 	= new ImtToaster();
				toastMessage.titleMessage		= ResourceManager.getInstance().getString('labels', 'error.title');
				toastMessage.message 			= ResourceManager.getInstance().getString('labels', 'error.createPatient') + " (" + ResourceManager.getInstance().getString('errors', ( fault as FaultEvent ).fault.faultString) +")";
				toastMessage.level 				= ImtToaster.ERROR;
				
				ApplicationModelLocator.getInstance().toaster.toast( toastMessage );
			}
		}
	}
}