MAth-Cloud-3.0.0/www.ipsocloud.com/intimamedia.com/flex/com/imt/intimamedia/commands/acquire/DeleteImageCommand.as

package com.imt.intimamedia.commands.acquire
{
	import com.adobe.cairngorm.control.CairngormEvent;
	import com.imt.flex.cairngormExtended.command.SuperCommand;
	import com.imt.flex.cairngormExtended.event.ChainEvent;
	import com.imt.intimamedia.business.AcquisitionDelegate;
	import com.imt.intimamedia.events.acquire.DeleteImagesEvent;
	import com.imt.intimamedia.events.acquire.SaveImageEvent;
	import com.imt.intimamedia.model.ApplicationModelLocator;
	import com.imt.intimamedia.views.common.ImtToaster;
	import com.imt.intimamedia.views.physician.acquire.AcquireView;
	
	import mx.resources.ResourceManager;
	import mx.rpc.events.FaultEvent;
	import mx.rpc.events.ResultEvent;
	
	import mx.controls.Alert;
	
	/**
	* Commande de suppression des images
	*/ 
	public class DeleteImageCommand extends SuperCommand
	{
		[Bindable]
		private var _model : ApplicationModelLocator = ApplicationModelLocator.getInstance();
		
		/**
		* Excecution de la commande
		* 
		* @param event Evénement de type CairngormEvent
		* @return void
		*/
		override public function execute( event : CairngormEvent ) : void
		{
			super.execute( event );
			
			nextEvent = ChainEvent( event ).nextChainedEvent;
			
			var delegate : AcquisitionDelegate = new AcquisitionDelegate( this );
			
			var deleteImageEvent : DeleteImagesEvent = DeleteImagesEvent( event );
			
			delegate.deleteImage( deleteImageEvent.dragAndDropVo, deleteImageEvent.appointment );
		}
		
		/**
		* Résultat de la commande
		* 
		* @param result Un objet 
		* @return void
		*/
		override public function result( result : Object ) : void
		{		
		    this.executeNextCommand();
		    
			var dispatcher : AcquireView = this.getDispatcher(this);
			
			var resultEvent : ResultEvent = ResultEvent( result );
			
			dispatcher.loadingPopUp.message = ResourceManager.getInstance().getString( "labels", "acquire.popUp.transfert.images.delete.done");
			dispatcher.loadingPopUp.progress.setProgress( 80, 100 );
		
			dispatcher.deleteMarkersEvent();
			
			super.result( result );
		}
		
		/**
		* Résultat de la commande
		* 
		* @param result Un objet 
		* @return void
		*/
		override public function fault( fault : Object ) : void
		{
			var dispatcher : AcquireView = this.getDispatcher(this);
			
			dispatcher.saveEnding();
			
			super.fault( fault );
			
			if (( fault as FaultEvent ).fault.faultString == ApplicationModelLocator.getInstance().ERROR_SESSION )
			{
				ApplicationModelLocator.displaySessionExpired( fault as FaultEvent );
			} 
			else 
			{			
				var toastMessage : ImtToaster = new ImtToaster();
				
				toastMessage.titleMessage		= ResourceManager.getInstance().getString('labels', 'error.title');
				toastMessage.message 			= ResourceManager.getInstance().getString('labels', 'error.deleteImage');
				toastMessage.level 				= ImtToaster.ERROR;
				
				_model.toaster.toast( toastMessage );
			}
		}
	}
}